Leadership By Numbers

In order to meet the criteria I listed above, no changes can be made to the Domino Directory and some sort of an user interface is required. I'd love to be able to create a handsome interface, but I have only two options: create a stand-alone application form which to launch a sophisticate UI to interface with the Domino Directory or use a custom toolbar icon. I do like the first option, but I'm going to choose the second, as it is the simplest, and probably an easier sell to the administrator (afterall, it goes into their own toolbar, and is not readily available to anyone else).

So, all you need to do is add the code below into a custom toolbar icon. Now you can (a) view all the notes.ini and location document settings that are included in a desktop setting; (b) delete any settings; and (c) add new entries or change existing ones.

REM {Copyrighted (C) 2005 by Jack Dausman http://LeadershipByNumbers.com -- you may copy and distribute this freely, but credit the source};
REM {I tried to make this code as readable as possible};

REM {Notes is good for identification, and I like to put the name of the user into any alerts};
v_name := @UpperCase(@Left(@Name([CN];@UserName);" "));

REM {Check to see if the right document has been selected, if not then generate an explanation};
@If(form="PolicyDesktop";"";@Return(@Prompt([Ok];"ALERT";v_name +", YOU DID NOT SELECT A DESKTOP POLICY DOCUMENT" + @Char(13) + "This script allows you to change your users' notes.ini" + @Char(13) + "settings and Location Document preferences" + @Char(13) + @Char(13) + "For more information:" + @Char(13) +"http://www.leadershipbynumbers.com")));

REM {Get all the fields in the document, then loop through them and pulling out the ones we need with their content};
v_docitems:= @Trim(@Transform(@DocFields;"var"; @If(@Begins(var;"$Pref":"LocAll");var +": "+ @Text(@GetField(var));"")));

REM {Provide the choices for user prompt. If you change these, then you'll need to change the contingent @If statement conditions};
v_choices := "View Existing Notes.Ini and Location Document Settings": "Add or Change A Notes.Ini Settings and Location Document": "Delete A Notes.Ini Settings and Location Document";

REM {Prompt for a choice};
v_setting:=@Prompt([OkCancelList]; v_name + ": SELECT A DESKTOP SETTING"; "Please select your note.ini or location document change";v_choices[1] ; v_choices);

REM {Delete field};
@If(v_setting="Delete A Notes.Ini Settings and Location Document"; @Return(@SetField(@Left(@Prompt([OkCancelList];v_name + ", CAUTION THIS WILL DELETE A SETTING !";"PICK AN INI OR LOCATION SETTINGS TO DELETE";v_docitems[1];v_docitems);":");@DeleteField));"");

REM {If all we need is to see the list, here it is};
@If(v_setting="View Existing Notes.Ini and Location Document Settings"; @Return(@Prompt([OkCancelList];"ALL INI AND LOCATION SETTINGS";"A COMPLETE LISTING OF ALL INI AND LOCATION SETTINGS";v_docitems[1];v_docitems)) ;"");

REM {Wouldn't it be nice to add some real explanations ? Unfortunately, the @prompt doesn't give a lot of text length with which to work. Notice that if the if statement doesn't catch the condition, it exits out of the code with an @Return. And if the user selects "cancel" it will exit out, as well, no -1 is returned};
@If(v_setting="Add or Change A Notes.Ini Settings and Location Document"; v_inisetting:=@Prompt([OkCancelEditCombo];"PROMPT 1 OF 2: SELECT OR ADD AN INI AND LOCATION SETTINGS"; "- To modify an existing value, simply select it without making any " + @Char(13)+ " changes to it or its value." + @Char(13)+ "- To add a new value you must enter in the correct format." +@Char(13) + " New client notes.ini setting are prefaced by " +"\"$Pref\" and" +@Char(13) + " location settings by \"LocAll\"" ;v_docitems[1];v_docitems) ;@Return(""));

REM {Double check that the prefix is correct};
@If(@Begins(v_inisetting;"$Pref":"LocAll");""; @Return(@Prompt([ok];v_name +{: ALERT};{THIS FORMAT DOES NOT HAVE A CORRECT PREFIX} +@Char(13)+ {IT MUST START WITH EITHER "$Pref" or "LocALL"} +@Char(13) + @Char(13) + {TRY AGAIN})));

rem {get setting name};
v_settingname:= @If(@Left(v_inisetting;":")="";v_inisetting;@Left(v_inisetting;":"));

rem {get new value, showing the old value if there was one}; v_value:=(@Prompt([okcanceledit];{PROMPT 2 OF 2: } +v_name +{, NOW ENTER THE VALUE FOR YOUR SETTING};{Value for } + v_settingname;@Right(v_inisetting;" ")));

rem {set setting value and it's all done};
@SetField(v_settingname;v_value);